roboticus did identify the error in the code you posted.

The code you posted is (with some minor changes).

Split the line into 4 named variables instead of @row (makes the problem clearer).

Eliminate quoting keys to the hash when they exist of all word characters (so don't need to be quoted). 

#!/usr/bin/perl
use strict;
use warnings;

my %results;
open my $fh, '<', 'file1.csv' or die $!;

while ( <$fh> ) {
    chomp ;
    my ($a1, $b1, $actDt, $inactDt) = split /,/;
    
    if (exists $results{$a1,$b1} ) {
    
        if ($actDt < $results{$a1,$b1}{ACTDATE}) {
            $results{$a1,$b1}{ACTDATE} = $actDt;
        }
            
        if (!$inactDt || !$results{$a1,$b1}{INACTDATE}) {
            $results{$a1,$b1}{INACTDATE} = '' ;
        }
        elsif($inactDt > $results{$a1,$b1}{INACTDATE} ) {
            $results{$a1,$b1}{INACTDATE} = $inactDt;
        }
    }
    else {  
        # Create new entry in hash
        $results{$a1,$b1} = {
            A1 => $a1,
            B1 => $b1,
            ACTDATE => $actDt,
            INACTDATE => $inactDt,
        };
    }
}
    
foreach ( sort keys %results ) {
    my $a1 = $results{ $_ }{A1} ;
    my $b1 = $results{ $_ }{B1} ;
    my $actDt = $results{ $_ }{ACTDATE};
    my $inactDt = $results{ $_ }{INACTDATE};
    print "$a1,$b1,$actDt,$inactDt\n" ;
}

[download]
The output gives erroneous results because you include non-contiguous records. The output with is: 
7900724655,200906888,20180416,20180830
7900724655,200906889,20180601,20180728
7900724655,200906890,20180905,
7900724666,200906868,20180416,20180830
7900724666,200906869,20180601,20180728
7900724666,200906890,20180905,

[download]

To get the results you want doesn't require a hash. 

#!/usr/bin/perl
use strict;
use warnings;

open my $fh, '<', 'file1.csv' or die $!;

my ($actDt, $inactDt, $count) = ('', '', 0);
my $previous_key = '';

while (<$fh>) {
    chomp;
    my ($a1, $b1, $begin, $end) = split /,/;
    my $key = "$a1,$b1";
    
    if ($previous_key eq $key) {
        $inactDt = $end;
        $count++;
    }
    else { # either reached the end of a record or this is the first r
+ecord
        print join(",", $previous_key, $actDt, $inactDt), "\n"
            if $count > 1;
        $actDt = $begin;
        $inactDt = $end;
        $count = 1;
    }
    $previous_key = $key;
}

print join(",", $previous_key, $actDt, $inactDt), "\n"
    if $count > 1;

[download]
This gives the desired results: 
7900724655,200906889,20180601,20180728
7900724655,200906890,20180905,
7900724666,200906869,20180601,20180728
7900724666,200906890,20180905,

[download]
The input file is: 
7900724655,200906888,20180416,20180522
7900724655,200906889,20180601,20180720
7900724655,200906889,20180724,20180728
7900724655,200906888,20180730,20180830
7900724655,200906890,20180905,20180930
7900724655,200906890,20181005,20181030
7900724655,200906890,20181104,
7900724666,200906868,20180416,20180522
7900724666,200906869,20180601,20180720
7900724666,200906869,20180724,20180728
7900724666,200906868,20180730,20180830
7900724666,200906890,20180905,20180930
7900724666,200906890,20181005,20181030
7900724666,200906890,20181104,

[download]

In reply to Re^5: sorting and merging in perl by Cristoforo
in thread sorting and merging in perl by Sekhar Reddy

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.