Hi, the correct solution depends on your specific needs, but marioroy's Perl Many-Core Engine offers several options. Please see MCE::Shared, MCE::Shared::Hash, MCE::Shared::Minidb, MCE::Shared::Cache.

From what I understand from your post, you basically want a shared DB where individual keys can be handled as with a cache, but sub-keys can also be accessed. Presumably you also need to be able to search for a key or keys by the value(s) of a sub-key or sub-keys). You might like: 

use strict; use warnings; use feature 'say';
use Data::Dumper;

use MCE::Shared;

my $db = MCE::Shared->minidb();

my %hash = ( problem => 'foo', technique => 'blorgle', answer => 41 );
my %junk = ( problem => 'bla', technique => 'blargle' );

$db->hset( my_key => %hash );
$db->hset( junkey => %junk ); # sorry for the bad pun

my $pid = fork;
die 'Fork failed' if not defined $pid;

if ( $pid == 0 ) { # child
    $db->happend( my_key => (problem => 'bar'));
    $db->hincr( my_key => 'answer');
    $db->hset( my_key => (technique => 'frobnicate') );
    exit;
}

# parent
wait;

my @rows = $db->select_href(':hashes', ':WHERE answer > 0');

say Dumper \@rows;

__END__

[download]
Output: 
$ perl monks/1226220.pl

$VAR1 = [
          [
            'my_key',
            {
              'answer' => 42,
              'problem' => 'foobar',
              'technique' => 'frobnicate'
            }
          ]
        ];

[download]

(A note from the doc that helps explain why the unfamiliar query syntax: "Several methods take a query string for an argument. The format of the string is described below. In the context of sharing, the query mechanism is beneficial for the shared-manager process. It is able to perform the query where the data resides versus the client-process grep locally involving lots of IPC.")

Hope this helps!


The way forward always starts with a minimal test.

In reply to Re: Sharing data "cache" between forked processes (MCE!) by 1nickt
in thread Sharing data "cache" between forked processes by Anonymous Monk

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.