The other examples listed here certainly work fine but since there's more than one way to do it, here's mine. I avoid slurping the file since I prefer to read in a line at a time if I don't know how big the input is going to be. If your input file is very large then slurping could use up quite a lot of memory. Also, my solution works regardless of the number of lines of numbers following each data record. 
#!/usr/bin/perl

use strict;
use warnings;

#print header line for output table
print "Movie\t\tShow\t\tCollection>20\n";

LINE: while(<DATA>)
{
    chomp;
    #find the record header
    next LINE if not /Movie="(\w+)"\s+show=(\d+)/;
    my ($movie,$show) = ($1,$2);
    my @numbers = ();
    while (($_ = <DATA>) =~ /\d+\s+\d+/)
    {
        chomp;
        push @numbers, (split " ");
    }
    #filter out just the numbers >= 20
    @numbers = grep {$_ >= 20} @numbers;
    #add up the numbers
    my $total = 0;
    $total += $_ foreach @numbers;

    print "$movie\t\t$show\t\t$total\n";
}

__DATA__
* Movie="ABC" show=4 
10 20 30 14 90 30
21 13 11 10 09 23
22 05 22 15 19 20

* Movie="XYZ" show=4 
10 20 30 14 90 30
21 13 11 10 09 23
22 05 22 15 19 10

[download]
Note that my solution produces different output than your example. You only count one occurrence of "22" on the last line but there are two. Is this by design? If so, you'd need to add a check to remove duplicate numbers (see How can I extract just the unique elements of an array? in perlfaq4).

In reply to (RhetTbull) Re: Arithmatic operation in PERL by RhetTbull
in thread Arithmatic operation in PERL by Anonymous Monk

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.