An unreliable program can be controlled from a perl program using the Expect.pm module. A description of the unreliable program and the use of the Expect module is presented.

I have a program that I need to run a large number of times. This program has a nasty bug in it. When you feed it bad data, it just sits there forever instead of providing a helpful error message. Bad Program!

I can't change the program, but I need to call this program inside a loop in my code. So I am using the perl Expect module to skip over the problem cases and continue with the rest of the runs of the program.

The Expect.pm module is capable of managing this process, so I wrote a few little test programs to help me understand how to accomplish this task.

I used this program to simulate an unreliable program. When it succeeds, this program just prints a simple message. When it fails, it just hangs. 
# unreliable.pl - Simulate a program that sometimes just hangs
if (rand(10) > 8){
  sleep 1 while 1 > 0;
}
else{
  print "--------------------------------\n",
        "It worked this time, no problems\n",
        "--------------------------------\n";
}

[download]

Expect.pm Test Program One
The following test program runs the unreliable program twenty times. If the unreliable program takes longer than five seconds, the attempt to run it is terminated and the test program continues. 

# timeout.pl - Expect Test Program
use Expect;
my $timeout=5;
foreach my $i (1..20)
{
  my $exp = Expect->spawn("./unreliable.pl")
    or die "Cannot spawn unreliable process $!\n";
  $exp->expect($timeout);
}

[download]

Expect.pm Test Program Two
The next version of the test program adds the feature that a message is printed for the cases when a timeout occurs.

use Expect;
my $timeout=5;

foreach my $i (1..20)
{
  my $exp = Expect->spawn("./unreliable.pl")
    or die "Cannot spawn unreliable process $!\n";

  $exp->expect($timeout,
    [
      timeout =>
        sub
        {
          print "Process timed out.\n";
        }
    ]
  );
}

[download]

Expect.pm Test Program Three
The next version of the test program adds a check to see if the unreliable program prints "It worked" somewhere in its output. If the test program detects this string, it prints "Status: OK" after the unreliable program runs. 

use Expect;

my $timeout=5;

foreach my $i (1..20)
{
  my $spawn_ok="not OK";

  my $exp = Expect->spawn("./unreliable.pl")
    or die "Cannot spawn unreliable process $!\n";

  $exp->expect($timeout,
    [
      'It worked',
        sub
        {
          $spawn_ok = "OK";
          exp_continue;
        }
    ],
    [
      timeout =>
        sub
        {
          print "Process timed out.\n";
        }
    ]
  );
  print "Status: $spawn_ok\n";
}

[download]

In reply to Using Expect.pm to Manage an Unreliable Program by toma

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.