This works, though not in the same order, and like BrowserUK's solution does not work for embedded quotes. (TMTOWTDI). 
use strict;
use warnings;

my $string = 'one two "three" four "five" six';

my (@quoted,@unquoted);

my $length = 0;
while ( $string =~ /\G\s*(?:("[^"]+")|([^"\s]+))(?:\s+)?/g  )
{
  if ( $1 ) { push @quoted,$1 }
  else { push @unquoted,$2 }
  $length = pos $string;
}

unless ( length($string) == $length ) { print "Quotes did not match" }
else  {
   local $\ ="\n";
   print q(@quoted:), join ",", @quoted;
   print q(@unquoted:),join ",",@unquoted;
}

[download]
And just for fun heres another solution:
use strict;
use warnings;

my $string = '  one two "three" four "five" six';

my (@quoted,@unquoted);

$\ ="\n";

1 while ( $string =~ s/"([^"]+)"/push @quoted,$1;''/ge );
if ( $string =~ /"/ ) { print q(A " was found so failure) and exit; }
push @unquoted, split " ", $string;

print q(@quoted:), join ",", @quoted;
print q(@unquoted:),join ",",@unquoted;

[download]
I doubt either solutions are the best solution. I think the best solution would depend on the strings and what you mean by a quoted string (can there be escaped quotes inside the string if so neither solution presented here will work). Well good luck, on your quest for knowledge.

-enlil

In reply to Re: separated quoted stings from unquoted strings by Enlil
in thread separated quoted stings from unquoted strings by Cody Pendant

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.