If have you a hash like so:

my %word = (
          'list' => 3,
          'thats' => 1,
          'value' => 2,
          'an' => 1,
          'would' => 1,
          'the' => 3,
          'at' => 1,
          'if' => 2,
);
[download]

First example - i want to print the above hash sorted by the keys in ascending order:

print "$_ => $word{$_}\n" for sort keys %word;
[download]

print "$_ => $word{$_}\n"
   for sort {$word{$a} <=> $word{$b}} keys %word;
[download]

Third example - sort first by the values in descending order this time, and then sort by the keys in ascending order:

print "$_ => $word{$_}\n"
   for sort {
      $word{$b} <=> $word{$a}     # sort values desc
         ||                       # if same, then
      $a cmp $b                   # sort keys asc
   } keys %word
;
[download]

use strict;
use warnings;

my %word;
while (<DATA>) {
   $word{"\L$_"}++ for map {s/\W//g;$_} split;
}
my $blank = delete $word{''};

printf("% 14s => %d\n",$_,$word{$_}) 
   for sort {
      $word{$b} <=> $word{$a}     # sort values desc
         ||                       # if same, then
      $a cmp $b                   # sort keys asc
   } keys %word
;

print "$blank 'errors' encountered\n";

__DATA__
I'm having a little trouble following the
documentation on pushing. It gives us the example:

    for $value (LIST) {
        $ARRAY[++$#ARRAY] = $value;
    }

I'm assuming (LIST) should be an array list, and
if that's so it would have been nice if they said
that in the docs because at first I thought it was
a filehandle of some kind.
[download]

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)