Consider using the preprocess and postprocess callback parameters to filter out and report files and directories you can't read. File::Find is recursive, so it's important to catch errors not only for the initial directory, but also for any files and directories beneath it.

Here's an example that shows how you might do this: 

#!/usr/bin/perl

use warnings;
use strict;

use File::Find;
use File::Spec::Functions;

my $directory = 'foodir';
my $size = 0;
my @unreadables = ();
my @errors = ();

sub wanted {
    # test: handling of @errors
    #local $_ = $_;
    #if (/foo\.txt/) {
    #    $_ = "nonexistentfile";
    #}
    
    if (stat) {
        -f _ and $size += -s _;
    }
    else {
        push @errors, catfile($File::Find::dir, $_) . " !$!";
    }
}

# filter unreadable directories
# from the list of files
# returned by readdir() before
# processing the directory:
# 
sub preprocess {
    my @readables;
    
    for (@_) {
        if (!-r) {
            push @unreadables, catfile($File::Find::dir, $_) . " !not 
+readable";
        }
        else {
            push @readables, $_;
        }
    }

    return @readables;
}


# post-directory processing:
# 
sub postprocess {
    unless (@unreadables or @errors) {
        return;
    }
    print "$_\n" for (@unreadables, @errors);
    @unreadables = @errors = ();
}

find(
    {
        wanted      => \&wanted,
        preprocess  => \&preprocess,
        postprocess => \&postprocess,
    },
    $directory
);

print "$directory size: $size\n";

[download]

In reply to Re: File::Find question by converter
in thread File::Find question by Concept99

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.