I also recommend a hash of coderefs. To give you a specific example, and some working code demonstrating two different approaches, here's a little quiz I fiddled with a few years ago. Problem: Given input of a string and a number, you want to call an appropriate handler function (based on the value of the string), passing it the number as an argument.

# Hash of coderef solution (recommended).
use strict;
use warnings;
my %op_table = ( edit  => sub {   my $z = shift;
                                  print "in EditHandler, z=$z\n";
                                  return 1;
                              },
                 chmod => sub {   my $z = shift;
                                  print "in ChmodHandler, z=$z\n";
                                  return 2;
                              }
               );
sub invoker {
   my ($name, $z) = @_;
   exists($op_table{$name}) or return -1;
   $op_table{$name}->($z);
}
# Example calls.
invoker("edit", 42);
invoker("chmod", 99);
invoker("fred", 7);      # returns -1
[download]

Perl symbol table solution.

use strict;
use warnings;
sub Handler::edit {
   my $z = shift;
   print "in EditHandler, z=$z\n";
   return 1;
}
sub Handler::chmod {
   my $z = shift;
   print "in ChmodHandler, z=$z\n";
   return 2;
}
sub invoker {
   my $handler = shift;
   exists($Handler::{$handler}) or return -1;
   &{$Handler::{$handler}};
}
# Example calls.
invoker("edit", 42);
invoker("chmod", 99);
invoker("fred", 7);      # returns -1
[download]

/-\

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.