package Simple::Class;
use strict;
use warnings;

use Class::MethodMaker
   new_hash_init => 'new',
   get_set => [qw(age name weight)],
;

sub load_data {
   return [ 
      map {
         Simple::Class->new({
            name   => $_,
            age    => int(rand(50))+20,
            weight => int(rand(150))+20,
         })
      } qw(bob bill brian babette bobo bix)
   ];
}

package main;
use strict;
use warnings;
use Data::Dumper;
use Template;

my $template = Template->new;
$template->process(\*DATA,{people => Simple::Class::load_data})
   || die $template->error;

__DATA__
[% colors = ['white','gray'] %]
<table>
   <tr><th>name</th><th>age</th><th>weight</th></tr>
   [% FOREACH person = people %]
      [% PROCESS row person = person %]
   [% END %]
</table>

[% BLOCK row %]
   [% color = colors.shift %]
   <tr>
      <td bgcolor="[% color %]">[% person.name %]</td>
      <td bgcolor="[% color %]">[% person.age %]</td>
      <td bgcolor="[% color %]">[% person.weight %]</td>
   </tr>
   [% colors.push(color) %]
[% END %]
[download]

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)