Why not create a dictionary of words with lists of offsets. Store the byte-location of the start of the line so then when you want to retrieve you seek immediately to the right location and print that line. Another idea is to store the offset of the n-th previous line so you can print some context.

I've written a function for you that accepts a filename and an optional number of lines of context ( the default being 1. You'll probably want to store the index somewhere using Storable so its convenient to re-use your index for later.

my @files = glob "*.txt";
my %file_idx = map {; $_ => index_file( $_, 5 ) } @files;

=pod

{    'foobar.txt' => {
        word => [ 1, 3, 5, 6 ],
        another => [ 5, 7, 2, ] },
    'barfoo.txt' => {
        .......
}

=cut

sub index_file {
    my $filename = shift;
    my $lines_of_context =
        $_[0] > 0
        ? shift()
        : 1;
    open my $fh, "<", $filename or die "Couldn't open $filename: $!";

    my @offsets;
    my %index;
    while ( my $line = <$fh> ) {
        push @offsets, tell $fh;
        my $offset =
            scalar( @offsets ) < $lines_of_context
            ? $offsets[0]
            : shift @offsets;
        for my $word ( split ' ', $line ) {
            push @{ $index{$word} }, $offset;
        }
    }

    close $fh or warn "Couldn't close $filename: $!";
    return \ %index;
}

[download]

In reply to Re: Re: Re: Simple Text Indexing by diotalevi
in thread Simple Text Indexing by cyocum

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.