What potential overhead? Perl will *not* recompile the regex in each iteration (unless you modify $from or $len). Here's a proof, assuming the program is in the file /tmp/qq: 
    $ perl -Dr /tmp/qq 2>&1 | grep Compiling
    Compiling REx `^(.{2}).{2}(.*)$'
    $

[download]
It only gets compiled once.

Here's a benchmark: 

#!/usr/bin/perl
                     
use strict;
use warnings;
                     
use Benchmark 'cmpthese';
    
our @data = <DATA>;
chomp @data;
                    
our $from = 2;
our $len  = 2;

our (@a, @b, @c);

cmpthese -10 => {
    substr   => 'for (@a = @data) {
                     substr $_, $from, $len, "" if length ($_) >= $fro
+m + $len
                 }',
    regex    => 'for (@b = @data) {
                     $_ = $1 . $2 if /^(.{$from}).{$len}(.*)$/;
                 }',
    regex_qr => 'my $qr = qr /^(.{$from}).{$len}(.*)$/;
                 for (@c = @data) {
                     $_ = $1 . $2 if /$qr/;
                 }',
};  

die "Unequal" unless "@a" eq "@b" && "@b" eq "@c";
                    
__DATA__
12345678
yellow
a
xx
yyy
a somewhat longer line to compensate for the smaller lines.
bla bla bla bla



            Rate regex_qr    regex   substr
regex_qr 38207/s       --      -3%     -62%
regex    39497/s       3%       --     -60%
substr   99555/s     161%     152%       --

[download]

Abigail

In reply to Re: How to remove character at certain position in the String..... by Abigail-II
in thread How to remove character at certain position in the String..... by bh_perl

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.