Unlike what cchampion is saying, you can do it in one regex, and even without using alternation and /g. A short benchmark even suggest it to be slightly faster than using two regexes. The regex: 
    s!^/*(.*[^/])/*$!/$1/!;

[download]
The benchmark: 
#!/usr/bin/perl

use strict;  
use warnings;

use Benchmark qw /timethese cmpthese/;

chomp (our @lines = <DATA>);

our (@r1, @r2, @r3);
cmpthese -10 => {
    mikedshelton  =>  '@r1 = map {local $_ = $_;
                                  s!^/*!/!;
                                  s!/*$!/!;   
                                  $_} @lines',  
    cchampion     =>  '@r2 = map {local $_ = $_;
                                  s{ (?: ^ /* | (?<=[^/])/* $ ) }</>xg
+;
                                  $_} @lines',  
    abigail       =>  '@r3 = map {local $_ = $_;
                                  s!^/*(.*[^/])/*$!/$1/!;
                                  $_} @lines',
};

die "Unequal\n" unless "@r1" eq "@r2" && "@r2" eq "@r3";

__END__
/foo/bar/baz/
foo/bar/baz/
/foo/bar/baz
foo/bar/baz
/
foo/bar
foo

[download]
And the results: 
                Rate    cchampion mikedshelton      abigail
cchampion     8069/s           --         -20%         -27%
mikedshelton 10038/s          24%           --          -9%
abigail      11057/s          37%          10%           --

[download]

Abigail

In reply to Re: Regex - one and only one / at beginning and end of file path by Abigail-II
in thread Regex - one and only one / at beginning and end of file path by mikedshelton

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.