Okay, here is some code to demonstrate the test that tilly described. I'm posting this because it gave me a couple of more chances to abuse the language. 

#!/usr/bin/perl -w

use strict;

exit main();

# This is not tilly's recommended test for how random an
# ordering is.  Repeatedly give a sorted list of numbers
# (if not using numbers, swap the < line for the "lt"
# line) to your randomizer and pass the results to
# cntincseq().  If your randomizer is good, then
# cntincseq() will return values that are distributed
# around something close to ( list size / 2 ).
sub cntincseq (\@) {
    my( $aList )= @_;
    my %seq;
    @seq{ 0..$#{$aList} }= @$aList;
    my( $idx, $cnt )= 0..1;
    while(  ++$idx < @$aList  ) {
        $cnt++  if  $seq{$idx} < $seq{$idx-1}
#       $cnt++  if  $seq{$idx} lt $seq{$idx-1}
    }
    return $cnt;
}

sub validate ($&$) {
    my( $cnt, $munge, $size )= @_;
    my @counts;
    for(  1..$cnt  ) {
        my @list= 1..$size;
        &$munge( \@list );
        push @counts, cntincseq( @list );
        print " ",$counts[-1];
    }
    return @counts;
}

sub fy {
    my( $aList )= @_;
    for(  reverse 2..@$aList  ) {
        my $i= rand($_);
        @$aList[$_-1,$i]= @$aList[$i,$_-1];
    }
}

sub hash {
    my %hash;
    for(  @{$_[0]}  ) {
        $hash{rand()}= $_;
    }
    @{$_[0]}= values %hash;
}

sub main {
    $|= 1;
    my $tot;
    my @counts= validate( 10, \&fy, 10000 );
    # And here we have a particularly nasty abuse
    # of C<map> for entertainment purposes only.
    # Do not use in production code!
    print "\nFisher-Yates: ",
        ($tot=0,map{$tot+=$_}@counts)[-1]/@counts, "\n";
    @counts= validate( 10, \&hash, 10000 );
    print "\nTye hash: ",
        ($tot=0,map{$tot+=$_}@counts)[-1]/@counts, "\n";
    return 0;
}

[download]

Here are the results of comparing Fisher-Yates to my hash randomizer: 

 4987 4974 5022 5012 5078 4967 4996 5007 4998 4990
Fisher-Yates: 5003.1
 4368 4542 4558 4529 4586 4601 4581 4566 4549 4535
Tye hash: 4541.5

[download]

Grumble... Back to that work on my bucketless hash table...

Update: Having just barely posted this, I think perhaps my test is similar but not quite the same as the test tilly described. I started writing the described test then mistakenly thought I could make it work on a wider selection of inputs, fixed what looked like a typo, and got a reasonable but different test out of it.

Update 2: And it isn't nearly as good of a test. I'll follow-up with some discussion in another node in a bit.

        - tye (but my friends call me "Tye")

In reply to RE: RE (tilly): Hashing the order out of an array (Re: Randomize an array) by tye
in thread Randomize an array by Zebu

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.