teabag,
I know people have their own preference on coding style, but I find the following much more readable:

#!/usr/bin/perl
use strict;
use warnings;

my $logfile  = $ARGV[0] || "/var/amavis/amavis.log";
my $fprotdir = $ARGV[1] || "/var/virusmails";
my $virprog  = $ARGV[2] || "f-prot";
my ($loc, $vir);

open(LOGFILE, '<', $logfile) or die "Unable to open $logfile for readi
+ng: $!";

while ( my $line = <LOGFILE> ) {
    chomp $line;
    if ( $line =~ /Infection:/ ) {
        ($loc, $vir) = ( split( / /, $line ) )[0, 3];
    }
    elsif ( $line =~ /quarantined/ ) {
        my ($file, $time, $month, $day) = ( split( / /, $line ) )[12, 
+3, 0, 2];
        my $date = "$day $month $time";
        print "At $date $virprog detected a virus\nfound in $loc\n";
        print "Name virus: $vir\nMessage saved as: $fprotdir/$file\n";
        Checkwhosi( $file );
    }

}
close LOGFILE or die "Unable to close $logfile : $!";

print "no viri received\n" if ! $vir;

sub Checkwhosi {
    my $file_name = shift;
    my $file_fqn = "$fprotdir/$file_name";

    open(VIRFILE, '<', $file_fqn) or die "Unable to open $file_fqn for
+ reading : $!";

    my ($senderserv, $sserv2, %header);
    while ( my $line = <VIRFILE> ) {
        chomp $line;
        if ( $line =~ /Received:/ ) {
            ($senderserv, $sserv2) = ( split( / /, $line ) )[2,3];
            $sserv2 =~ s/[(\[\]]//g;
        }
        elsif ( $line =~ /(From|To|Subject):/ ) {
            $header{ $1 } = ( split( / /, $line ) )[1];
        }
    }
    print map{defined $header{$_} ? "$_: $header{$_}\n" : () } qw(To F
+rom Subject);
    print "Virus Mailserver: $senderserv\nipadres server: $sserv2\n";
    print "-" x 23, "\n";

    close(VIRFILE) || die "Error closing viral log file: $!";
}
[download]

Cheers - L~R

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.