Take the regexp /(\w)(\w)/, and the string "same old show".

$_ = "same old show";

# scalar, one at a time:
while(/(\w)(\w)/g) {
    print "while: $1 (+ $2)\n";
}

# list context, one go
@list = /(\w)(\w)/g;
print "List: @list\n";

# list context, foreach loop
foreach(/(\w)(\w)/g) {
    print "foreach: $_\n";
}
[download]

while: s (+ a)
while: m (+ e)
while: o (+ l)
while: s (+ h)
while: o (+ w)
List: s a m e o l s h o w
foreach: s
foreach: a
foreach: m
foreach: e
foreach: o
foreach: l
foreach: s
foreach: h
foreach: o
foreach: w

OTOH the while takes one pair of matched items each time, thus it'll loop half as many times.

In your particular example, the regexp is /((.))/. You still have a $1 and a $2, even though they capture the same thing — but you ignore $2. That's why you don't see it appear. Modifying my code to match your regexp and string, I get:

$_ = "abc";

# scalar, one at a time:
while(/((.))/g) {
    print "while: $1 (+ $2)\n";
}

# list context, one go
@list = /((.))/g;
print "List: @list\n";

# list context, foreach loop
foreach(/((.))/g) {
    print "foreach: $_\n";
}
[download]

while: a (+ a)
while: b (+ b)
while: c (+ c)
List: a a b b c c
foreach: a
foreach: a
foreach: b
foreach: b
foreach: c
foreach: c

In summary: you simply ignored to output the contents of $2 in your first snippet, the while loop.