Here is an example illustrating the problem. First is the output, followed by sample code:

Fetching text file small.txt
Displaying response object contents:
<?xml version="1.0"?>
<methodResponse>
  <params>
    <param>
      <value>
        <string>This is a small text file.
</string>
      </value>
    </param>
  </params>
</methodResponse>

Fetching text file small.xml
Displaying response as plain text:
Unknown tag encountered: Something
[download]

In the first case, the contents of a plain (non-XML) text file is sent, and the method call succeeds.

In the second case, the contents of a small XML file are sent, and the send_request() method fails with the error message "Unknown tag encountered: Something". (it returns a descriptive string on error, or an RPC::XML::response object reference on success). The string "Something" is the tag name of the root element in the sample application XML data that is sent.

RPC::XML server:

#!/usr/bin/perl -w

use strict;
use RPC::XML::Server;

my $server = RPC::XML::Server->new(port => 9000);

$server->add_method(
    {
        name        => 'dump_file',
        version     => '1.0',
        hidden      =>  0,
        code        => \&dump_file,
        signature   => [ 'string string' ],
        help        => 'Dumps the contents of the specified file'
    }
);

$server->server_loop();

sub dump_file {
    my $server = shift;
    my $fname  = shift;
    my $buffer;

    print "Calling dump_file\n";

    if (-f $fname) {
        print "    Dumping contents of file $fname\n";
        open(FILE, $fname);

        $buffer = join('', (<FILE>));
    } else {
        print "Can't find file $fname: $!\n";
        return undef;
    }

    return $buffer;
}
[download]

RPC::XML client:

#!/usr/bin/perl -w

use strict;
use RPC::XML::Client;

my $client  = RPC::XML::Client->new('http://localhost:9000/');

my @files = qw(small.txt small.xml);
my ($request, $response);


foreach my $file (@files) {
    print "Fetching text file $file\n";

    $request    = RPC::XML::request->new('dump_file', $file);
    $response   = $client->send_request($request);

    display_response($response);
}

sub display_response {
    my $response = shift;

    if (ref($response) && $response->can('as_string')) {
        print "Displaying response object contents:\n",
            $response->as_string(), "\n";
    } else {
        print "Displaying response as plain text:\n", $response, "\n";
    }
}
[download]

Sample text file:

This is a small text file.
[download]

Sample XML file:

<Something>
    <SubElement>
        <Foo/>
        <Bar baz="mumble"/>
    </SubElement>
</Something>
[download]