This came up on perl5-porters this week:

The question is, when does the object get destroyed given this code?

if (my $object = Foo->new) {}
print "after if\n";

package Foo;
sub new { my $self = bless {},shift; print "CREATED $self\n"; $self }
sub DESTROY { print "DESTROYED $_[0]\n" }
[download]

Well, contrary to expectation (well, at least mine), the object does not get destroyed until global destruction! As the following output shows:

CREATED Foo=HASH(0xfc65c)
after if
DESTROYED Foo=HASH(0xfc65c)
[download]

instead of the expected:

CREATED Foo=HASH(0xfc65c)
DESTROYED Foo=HASH(0xfc65c)
after if
[download]

It appears that this behaviour is intentional and goes back until at least 5.00504. It is caused by the fact that any lexical inside an if() gets a refcount of 2, rather than of 1.

If this really is a problem for you, then there is the Internals module which allows you to set the refcount of a variable from Perl.

use Internals qw(SetRefCount);
if (my $object = Foo->new) { SetRefCount( $object,1 ) }
print "after if\n";

package Foo;
sub new { my $self = bless {},shift; print "CREATED $self\n"; $self }
sub DESTROY { print "DESTROYED $_[0]\n" }
__END__
CREATED Foo=HASH(0xfc65c)
DESTROYED Foo=HASH(0xfc65c)
after if
Attempt to free unreferenced scalar: SV 0xfc65c.
[download]

Note that the object now is destroyed at the end of the if(), but that we get a warning at global destruction as a bonus.

Of course, there is a much simpler method: just add an extra scope!

{
if (my $object = Foo->new) { }
}
print "after if\n";

package Foo;
sub new { my $self = bless {},shift; print "CREATED $self\n"; $self }
sub DESTROY { print "DESTROYED $_[0]\n" }
__END__
CREATED Foo=HASH(0xfc65c)
DESTROYED Foo=HASH(0xfc65c)
after if
[download]

Hope this maybe helpful for someone someday.

Liz

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.