I would personally manage the data internally, but you could always look at perltie and write an appropriate tie class that did it for you. Here is an example class: 
package Tie::Input::Insertable;

sub PRINT {
  my $self = shift;
  $self->{buffer} = join '', @_, $self->{buffer};
}

sub TIEHANDLE {
  my ($class, $fh) = @_;
  bless {fh => $fh, buffer => ""}, $class;
}

sub READLINE {
  my $self = shift;
  return undef if $self->{eof};
  while (-1 == index($self->{buffer}, $/)) {
    my $fh = $self->{fh};
    my $data = <$fh>;
    if (length($data)) {
      $self->{buffer} .= $data;
    }
    else {
      $self->{eof} = 1;
      return delete $self->{buffer};
    }
  }
  my $pos = index($self->{buffer}, $/) + length($/);
  return substr($self->{buffer}, 0, $pos, "");
}

sub EOF {
  my $self = shift;
  $self->{eof} ||= not length($self->{buffer}) or $self->{fh}->eof();
}

1;

[download]
Save that in Tie/Input/Insertable.pm and then you can do the following: 
use Tie::Input::Insertable;
tie *FOO, 'TIE::Input::Insertable', *STDIN;

while (<FOO>) {
  print FOO "Hello, world\n" if /foo/;
  print $_;
}

[download]
Note that I made the tied handle not be the one that I was tying it to. If you do that, then you are playing on the edges of infinite recursion. Just make the handles different and you avoid lots of possible confusion.

In reply to Re: Manipulating STDIN by tilly
in thread Manipulating STDIN by ChwanRen

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.