You need to fully qualify the package in which the DATA section you wish to access resides. One way to do so is given below in the flux sub.

Update: Summary (click readmore for full test code and output): 

sub flux {
  my $class = ref shift;
  my $fh = do {
    no strict 'refs';
    \*{"$class\::DATA"};
  };
  return "A-flux: " . scalar <$fh>;
}

[download]

344569.pl 

#!/usr/bin/perl
use warnings;
use strict;

use a344569;
use b344569;

my $a = a344569->new();
my $b = b344569->new();

print "A:\n";
print "  ", $a->foo();
print "  ", $a->flux();

print "B:\n";
print "  ", $b->foo();
print "  ", $b->bar();
print "  ", $b->flux();

print "Ok\n";

[download]

a344569.pm 

package a344569;

use strict;

sub new {
  return bless {}, shift;
}

sub foo {
  return "A-foo: " . scalar <DATA>;
}

sub flux {
  my $class = ref shift;
  my $fh = do {
    no strict 'refs';
    \*{"$class\::DATA"};
  };
  return "A-flux: " . scalar <$fh>;
}

1;

__DATA__
This is package A
This is package A
This is package A
This is package A

[download]

b344569.pm 

package b344569;

@ISA = ('a344569');

use strict;

sub bar {
  return "B-bar: " . scalar <DATA>;
}

1;

__DATA__
This is package B
This is package B
This is package B
This is package B

[download]

Produces: 

[johnsca@cory tmp]$ ./344569.pl 
A:
  A-foo: This is package A
  A-flux: This is package A
B:
  A-foo: This is package A
  B-bar: This is package B
  A-flux: This is package B
Ok

[download]

bbfu
Black flowers blossom
Fearless on my breath

In reply to Re: inheritance and __DATA__ by bbfu
in thread inheritance and __DATA__ by thpfft

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.