Looking at the code near the line on which the error was reported, we find this set method in 5.6.1:

# IPC/Msg.pm lines 61-79
sub set {
    my $self = shift;
    my $ds;

    if(@_ == 1) {
        $ds = shift;
    }
    else {
        croak 'Bad arg count' if @_ % 2;
        my %arg = @_;
        my $ds = $self->stat
                or return undef;
        my($key,$val);
        $ds->$key($val)
            while(($key,$val) = each %arg);
    }

    msgctl($$self,IPC_SET,$ds->pack);
}

[download]

There is a bug in this code: on line 11 (which is line 71 of the original file), my $ds creates a new $ds variable which goes out of scope at the end of the else block. That is why the final line has an undefined value for $ds when it tries to invoke $ds->pack.

Removing the redundant "my" will fix that problem by ensuring that (as intended) the outer $ds variable is the one used, and indeed in later perls you'll find that exactly this change has been made: replacing

  my $ds = $self->stat

[download]
with
  $ds = $self->stat

[download]
at line 71.

If you don't have permission to make this fix to the code directly, and you can't convince the system administrator to apply the fix for you, there are a couple of ways you can get around it. One way is subclassing to replace the buggy routine:

  {
    package IPC::Msg::Bugfix;
    our @ISA = qw/ IPC::Msg /;
    sub set {
      # corrected version of set here ...
    }
  }
  # in your code
  my $msg = new IPC::Msg::Bugfix('24h', IPC_CREAT);
  # and continue as before

[download]

An alternative is to recode to avoid the path with the bug in it:

  # avoiding buggy multiple-arg set()
  # $msg->set('qbytes' => 32768); 
  my $ds = $msg->stat or die "stat: $!";
  $ds->qbytes(32768);
  $msg->set($ds);

[download]

(Please note, I haven't tested any of this code.)

Hugo

In reply to Re^3: Resizing IPC::Msg queue size by hv
in thread Resizing IPC::Msg queue size by Jeppe

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.