Zaxo's answer is probably the best for just using a pre-call hook. But if you need a little more control over calling the old sub, you may need to do it yourself.

I don't see the problem with strict. Just turn off strict refs locally and use symbolic references, it's a lot easier than messing with eval. Part of strict is knowing when you should turn it off. Messing with the symbol table is one of those times. Just make sure you don't turn off strict refs inside that closure that becomes the new sub, though. 

package Foo;
sub bar { print "Original Foo::bar\n"; }

package main;

sub switcheroo {
    my ($pkg, $func) = @_;

    my $old_ref = do {
        no strict 'refs';
        \&{"$pkg\::$func"};
    };

    my $new_ref = sub {
        print "New $func\n";
        $old_ref->();
    };

    {
        no strict 'refs';
        *{"$pkg\::$func"} = $new_ref;
    }
}

Foo::bar();
switcheroo("Foo", "bar");
Foo::bar();

[download]
You may also want to use goto &$old_ref in case the original sub wanted to look at caller.

blokhead

In reply to Re: Advanced subroutine and symbol table manipultation by blokhead
in thread Advanced subroutine and symbol table manipultation by Tuppence

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.