I used it for the first time yesterday to pseudo-insert new items into my foreach list:

sub line_wrap {
   my ($str, $max) = @_;

   my $line;
   my @lines;

   foreach $line (split($BRK, $str))
   {
      # # Collapse spaces and tabs.
      # s/\s+/ /g;

      if (length($line) > $max)
      {
         my $max2 = $max - 1;
         if ($line =~ s/^(.{0,$max2}\S)\s+//s)
         {  # Break at space.
            push(@lines, $1);
         }
         else
         {  # No space.
            $line =~ s/^(.{0,$max})//s;
            push(@lines, $1);
         }

         # Check if remainder needs to be broken.
         redo;
      }
      else
      {  # No need to break.
         push(@lines, $line);
      }
   }

   return join("\n", @lines) . "\n";
}
[download]

Of course, I could very simply rewrite the 'if' as a 'while' to eliminate the 'redo'.

sub line_wrap {
   my ($str, $max) = @_;

   my $line;
   my @lines;

   foreach $line (split($BRK, $str))
   {
      # # Collapse spaces and tabs.
      # s/\s+/ /g;

      while (length($line) > $max)
      {
         my $max2 = $max - 1;
         if ($line =~ s/^(.{0,$max2}\S)\s+//s)
         {  # Break at space.
            push(@lines, $1);
         }
         else
         {  # No space.
            $line =~ s/^(.{0,$max})//s;
            push(@lines, $1);
         }
      }

      push(@lines, $line);
   }

   return join("\n", @lines) . "\n";
}
[download]

In short
redo unless ...;
replaces a nested loop, possibly making it easier to read.