I don't seem to have any trouble with what I think you want. Does the following code work for you?

#!/usr/bin/perl

use strict;
use warnings;

package Parent;

sub new
{
    bless {}, shift;
}

sub DESTROY {}

sub AUTOLOAD
{
    our $AUTOLOAD;
    my $self = shift;
    print "Parent called for '$AUTOLOAD' on $self\n";
}

package Child;

our @ISA = 'Parent';

sub AUTOLOAD
{
    our $AUTOLOAD;
    my $self     = shift;
    my ($method) = $AUTOLOAD =~ /::(\w+)$/;
    my $parent   = "SUPER::$method";
    return $self->$parent( @_ ) unless $method =~ /^kid_/;
    print "Child called for '$method' on $self\n";
}

package Grandchild;

our @ISA = 'Child';

sub AUTOLOAD
{
    our $AUTOLOAD;

    my $self     = shift;
    my ($method) = $AUTOLOAD =~ /::(\w+)$/;
    my $parent   = "SUPER::$method";
    return $self->$parent( @_ ) unless $method =~ /^grandkid_/;
    print "Grandchild called for '$method' on $self\n";
}

package main;

print "Constructors\n";

my $p  = Parent->new();
my $k  = Child->new();
my $gc = Grandchild->new();

print "Calling foo() on all\n";

$p->foo();
$k->foo();
$gc->foo();

print "Calling kid_foo() on child and grandchild\n";

$k->kid_foo();
$gc->kid_foo();

print "Calling grandkid_foo() on grandchild\n";

$gc->grandkid_foo();

[download]

In reply to Re: More then one AUTOLOAD in a class hierarchy. by chromatic
in thread More then one AUTOLOAD in a class hierarchy. by ced

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.