I'm going to assume that the timestamp lines are unique and that duplicate blocks don't have to have the same timestamps. 
#! /usr/bin/perl

use strict;
use warnings;

my ($key, %hash, @keys);
while (<DATA>) {
        if (/^\@:\d{10,}:(?:\d{10,})?:1$/) {
                chomp;
                $key = $_;
                # needed to process keys in file order
                push @keys, $key;
        } else {
                $hash{$key} .= $_;
        }
}

my ($value, %revhash);
# changed to foreach to process keys in file order
# while(($key, $value) = each %hash) {
foreach $key (@keys) {
        $value = $hash{$key};
        if(exists($revhash{$value})){
                print "$key is a duplicate of $revhash{$value}\n";
        } else {
                $revhash{$value} = $key;
        }
}

__DATA__
@:1107530184::1
kkkkkkkkkkkkmkmkmk
kkkkkk
confused.gif
@:1107530257:1107530439:1
kmkmkm
<br>kmkmkm
<br>
<br>Fri Feb  4 10:17:37 2005
<br>
mad.gif
@:1107530709::1
ygyg
ygygygyg
lol.gif
@:1107530717::1
ygyg
ygygygyg
lol.gif
@:1107530963::1
cool
help
cool.gif
@:1107532649:1107532689:1
k
<br>kkkkkkkkkkkkkkkkk
<br>
<br>Fri Feb  4 10:57:29 2005
<br>
lol
lol.gif
@:1107532758::1
lll
Lets
mad.gif
@:1107532976::1
lll
Lets
mad.gif

[download]
And the output is: 
@:1107530717::1 is a duplicate of @:1107530709::1
@:1107532976::1 is a duplicate of @:1107532758::1

[download]
Update: If you only want to eliminate one block from each pair of consecutive duplicate blocks then this might work: 
undef $/;
my $file = <DATA>;
$file =~ s/^\@:\d{10,}:(?:\d{10,})?:1\n(.*?)
          (^\@:\d{10,}:(?:\d{10,})?:1\n\1)/$2/msxg;
print $file;

[download]

In reply to Re: Regular Expression to find duplicate text blocks by jdalbec
in thread Regular Expression to find duplicate text blocks by Anonymous Monk

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.