# ####################
#
# BUG: Assumes less than 5000 messages per minute.
#      There is not enough data to avoid this problem.
#
# BUG: Does not handle messages across different years correctly.
#      There is not enough data to avoid this problem.
#
# ####################

use strict;
use warnings;

use vars qw( %MONTH_TO_INDEX );

BEGIN {
   %MONTH_TO_INDEX = qw(
      Jan  1   Feb  2   Mar  3   Apr  4
      May  5   Jun  6   Jul  7   Aug  8
      Sep  9   Oct 10   Nov 11   Dec 12
   );
}


my $header = <DATA>;
my @data   = <DATA>;

my @sort_data = map  { $_->[5] }
                sort { $a->[0] <=> $b->[0] ||
                       $a->[1] <=> $b->[1] ||
                       $a->[2] <=> $b->[2] ||
                       $a->[3] <=> $b->[3] ||
                       (abs($a->[4] - $b->[4]) < 5000
                          ? ($a->[4] <=> $b->[4])
                          : ($b->[4] <=> $a->[4])
                       ) }
                map  { /^(\d+) \| (\D+)(\d+) \| (\d+):(\d+)/;
                       [
                          $MONTH_TO_INDEX{$2}, # 0: Month
                          0+$3,                # 1: Day
                          0+$4,                # 2: Hour
                          0+$5,                # 3: Minute
                          0+$1,                # 4: id
                          $_,                  # 5: Input
                       ] }
                @data;


print($header, @sort_data);

__DATA__
Transid | Date | Time | PagerID | Message Description 
00004 | Feb10 | 11:18 | sundallas_e | dspmmr3 at ...
00005 | Feb10 | 11:18 | sundallas_e | dspmmr3 at ...
99996 | Feb10 | 11:18 | sundallas_e | dspmmr3 at ...
00000 | Feb11 | 11:17 | hpdallas_e | zcompass at ...
00001 | Feb10 | 11:17 | hpdallas_e | zcompass at ...
99995 | Feb10 | 11:17 | hpdallas_e | zcompass at ...

[download]

Outputs:

Transid | Date | Time | PagerID | Message Description
99995 | Feb10 | 11:17 | hpdallas_e | zcompass at ...
00001 | Feb10 | 11:17 | hpdallas_e | zcompass at ...
99996 | Feb10 | 11:18 | sundallas_e | dspmmr3 at ...
00004 | Feb10 | 11:18 | sundallas_e | dspmmr3 at ...
00005 | Feb10 | 11:18 | sundallas_e | dspmmr3 at ...
00000 | Feb11 | 11:17 | hpdallas_e | zcompass at ...

[download]

In reply to Re: Sorting through a rollover by ikegami
in thread Sorting through a rollover by onegative

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.