For a simple case (where you are only allow a single item to be selected at a time, you could try something like this: 
use Tk;
use strict;
use warnings;

my $value;

my $mw = MainWindow->new;

my $entry = $mw->Entry(
   -state => 'readonly',
   -textvariable => \$value
)->pack;

my $lb = $mw->Listbox(
   -height => 0
)->pack;
$lb->insert('end', qw/one two three four five six/);
$lb->bind('<ButtonPress-3>', [\&setItem, \$value, Ev('@')]);

sub setItem
{
   my ($lb, $valSR, $xy) = @_;

   $lb->selectionClear(0, 'end');
   my $index = $lb->index($xy);
   if (defined($index)) 
   {
      $lb->selectionSet($index);
      $$valSR = $lb->get($index);
   }
}

MainLoop;

[download]
A slight variation of this: 
use Tk;
use strict;
use warnings;

my $value;

my $mw = MainWindow->new;

my $entry = $mw->Entry(
   -state => 'readonly',
   -textvariable => \$value
)->pack;

my $lb = $mw->Listbox(
   -height => 0
)->pack;
$lb->insert('end', qw/one two three four five six/);
$lb->bind('<ButtonPress-3>', [\&setItem, \$value]);

sub setItem
{
   my ($lb, $valSR) = @_;
   my $xy = $lb->XEvent->xy;
   $lb->selectionClear(0, 'end');
   my $index = $lb->index($xy);
   if (defined($index)) 
   {
      $lb->selectionSet($index);
      $$valSR = $lb->get($index);
   }
}

MainLoop;

[download]
Note the modification to the <Button-3> bind, and the first two lines of the setItem sub. I used to prefer the latter rather than the former, because I thought that it was easier to read, but I've since changed my mind -- especially when coding a Tk module, because I find the former is easier to unit-test reliably across different platforms. Your mileage may vary...

In reply to Re: Tk listbox item select by rcseege
in thread Tk listbox item select by kgb_321

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.