#! perl -slw
use strict;
use IO::File;
use threads;
use threads::shared;

BEGIN {
    $| = 1;
    our $TRACE ||= 0;
    print "TRACE=$TRACE";
    *CORE::GLOBAL::warn = sub {} unless $TRACE;
}

sub processData {
    printf @_;
}

sub getDataT {
    my ( $handle, $sharedDataRef, $doneRef ) = @_;
    while( !$$doneRef ) {
            warn "t-Locking" . $/;
        lock $$sharedDataRef;
            warn 't-Waiting' . $/;
        cond_wait( $$sharedDataRef ) while $$sharedDataRef;
            warn 't-Setting' . $/;
        $$sharedDataRef = $handle->getline;

        # set $done before handing the data over to the main thread
        $$doneRef = 1 if $handle->eof;
            warn 't-Signalling' . $/;
        cond_signal( $$sharedDataRef );
    }
    return;
}

my $handle = IO::File->new( $ARGV[ 0 ], 'r' );
my $sharedData :shared;
my $done :shared = 0;
threads->create( \&getDataT, $handle, \$sharedData, \$done );

while( !$done ) {
        warn 'm-locking' . $/;
    lock $sharedData;
        warn 'm-waiting' . $/;
    cond_wait $sharedData until $sharedData || $done;
        warn 'm-Copying' . $/;
    my $localCopy = $sharedData;
        warn 'm-undefing' . $/;
    undef( $sharedData );
        warn 'm-signalling' . $/;
    cond_signal $sharedData;
        warn 'm-processing' . $/;
    processData( $localCopy );
}
[download]