FWIW, push seems to be faster than direct indexing on a pre-grown array, as the following table shows.

The only difference between the windex and windex_2 alternatives in the following table is that the former uses push and the latter uses direct indexing on a pre-grown array. The size of the string is 100_000, containing about 3800 matches. (Full code within the readmore tags.) 

          Rate   wregex windex_2   windex
wregex   212/s       --     -24%     -32%
windex_2 277/s      31%       --     -11%
windex   310/s      47%      12%       --

[download]

use strict;
use warnings;

use Benchmark 'cmpthese';

srand( 0 );
my $s = join '', map chr(97+int(rand(26))), 1..100_000;
my $n = $s =~ tr/a/a/;
print "$n\n";

cmpthese( -1,
          {
           windex   => \&windex,
           windex_2 => \&windex_2,
           wregex   => \&wregex,
          }
        );

sub windex {
  my @o;
  my $o = -1;
  while ( ( $o = index( $s, 'a', $o+1 )) > -1 ) { push @o, $o }
  return;
}

sub windex_2 {
  my @o;
  $#o = $n - 1;
  my $o = -1;
  my $i = 0;
  while ( ( $o = index( $s, 'a', $o+1 )) > -1 ) { $o[ $i++ ] = $o }
  return;
}

sub wregex {
  my @o;
  $s =~ m/a(?{ push @o, pos() - 1 })(?!)/;
  return;
}
__END__
3797
          Rate   wregex windex_2   windex
wregex   212/s       --     -24%     -32%
windex_2 277/s      31%       --     -11%
windex   310/s      47%      12%       --

[download]

the lowliest monk

In reply to Re^3: Producing a list of offsets efficiently by tlm
in thread Producing a list of offsets efficiently by BrowserUk

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.