Here's a P5 version. It's broken down into very simple pieces, because I couldn't wrap my mind around this approach any other way. Conceptually, I think it's very straightforward (and I like how the main routine is just a reduce of a map -- very functional-flavored). 
use warnings;
use strict;

nested_for(
          [[1..2], ['a'..'c'], ['A'..'D']],
           sub {print "Printing! [@_]\n";}
);

my $i = nested_for([[qw(r o y)],sub{[$_]}, [qw(b i v)]]);
my @args;
print "@args\n" while @args = $i->();

# Handles the coderef arg, if any
sub nested_for {
    my @loops = @{shift()};
    if (@_) {
        my $fn = shift;
        my @args;
        my $i = ret_iter(@loops);
        $fn->(@args) while @args = $i->();
    }
    else {
        return ret_iter(@loops);
    }
}

# Turns a list into a self-resetting iterator
# (upon completing iterations, it returns empty-list, then
# the next iteration is back at the beginning)
sub mk_iter {
    my $ref = $_[0];
    my $i = 0;
    return sub {
        my @items;
        @items = @{(ref $ref eq 'CODE') ? $ref->() : $ref}
          unless @items;
        if ($i > $#items) {
            $i = 0;
            @items = @{$ref->()} if ref $ref eq 'CODE';
            return ();
        } else {
            return $items[$i++];
        }
    }
}

# Like map for two iterators, returning an iterator
sub nest {
    my ($outer, $inner) = @_;
    my @out = $outer->();
    return sub {
        local $_ = $out[$#out];
        my @in = $inner->();
        unless (@in) {
            return unless @out = $outer->();
            $_ = $out[$#out];
            @in = $inner->();
        }
        return (@out, @in);
    };
}


use List::Util 'reduce';
sub ret_iter {
    reduce {nest($a, $b)} map mk_iter($_), @_;
}

[download]
Caution: Contents may have been coded under pressure.

In reply to Re^3: Perl6 Contest #2: P6 That Doesn't Look Like P5 by Roy Johnson
in thread Perl6 Contest #2: P6 That Doesn't Look Like P5 by Limbic~Region

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.