type is just for creating a type-synonym. It doesn't really create a new type, but it can make your code easier to understand by giving a more meaningful name to an existing type. For example:

type Name = String

lowerName :: Name -> Name
lowerName = map toLower

-- then:
lowerName "KELAN" -- evaluates to "kelan"
[download]

In the above, the types Name and String can be used interchangeably, but using Name appropriately can make the code's intent clearer.

data is for defining a completely new type. This confused me at first, too, because the keyword data doesn't seem to relate to types. I'm guessing that the reason for that keyword is because this construct is used to define the data constructors for the type. Example:

data Piece = Pawn | Rook | Knight | Bishop | Queen | King

-- The type is 'Piece', and to construct an actual value of
-- that type, you use one of the six data constructors.

promotesTo :: Piece -> [Piece]
promotesTo Pawn = [ Rook, Knight, Bishop, Queen ]
promotesTo _ = []

-- then:
promotesTo Pawn -- evaluates to [Rook, Knight, Bishop, Queen]
promotesTo $ head $ promotesTo Pawn -- evaluates to []
[download]

And data constructors can take parameters, and each can take different numbers of parameters:

data Rectangle
    = UnitSquare
    | Square Int
    | Rect Int Int

-- examples of values for each would be:
v1 :: Rectangle
v1 = UnitSquare

v2 :: Rectangle
v2 = Square 3

v3 :: Rectangle
v3 = Rect 5 9
[download]

Probably what confused me the most about the data construct when I started learning it was that the examples used the same word for the typename and the data constructor, so it was unclear that they are actually separate ideas.

newtype, as the Anonymous Monk said, is the same as data, except there can be only one data constructor, and it gets optimized away for lower overhead.

A reference I found helpful when learning about type and data was Tour of the Haskell Syntax, which gives the actual syntax in a clear and concise form.