I remember doing this game when I was first learning in BASIC. And then the corrolary - you pick the number, the computer guesses it. I learned binary searches that day, without realising it. ;-)

Comments:

• use strict; use warnings; Always. Unless you know what you're doing.
• Formatting. There are two major styles of braces. I'd suggest picking one. Although there can be religious wars on the topic of which one, and I have my preference as well, I'm not going to offer more advice than "just pick one".
• Indentation. Whitespace is your friend. Make blocks of code easier to follow by lining up the left indent approprately.
• Next is the use of goto. Although it has some uses, most of them are for advanced users only. As in, only once you've mastered not using goto can you give a reasonable justification for using it. At least, that's my opinion on using goto. In this case, you're using it to somewhat emulate a while loop. So just use a while loop, and people (like me) won't complain. To this end, I'd put the game itself into a "game" subroutine, and then be able to just wrap the call to the game sub in a small while loop.
• Generally speaking, a single line of output is represented by a single print statement. Exceptions to this, unlike the exceptions to goto, are commonplace, however, so don't take this as a hard-and-fast rule or anything. For example, instead of

      print "Sorry, you ran out of guesses.  My number was ";
      print $value;
      print ". \n";
  [download]

  use

      print "Sorry, you ran out of guesses.  My number was ", $value, ".
  +\n";
  [download]

  Some people will use perl's interpolation to do this as:

      print "Sorry, you ran out of guesses.  My number was $value.\n";
  [download]

  The former may be faster, but in reality the deciding factor should be what you find to be more readable.
• Comments ... should go before what they're commenting, not after. Code is not a suspense novel - you shouldn't need to wait to see what really is happening. Code should be extremely boring where the plot is revealed before anything happens.

#Guessing Game
#You only get 10 tries!
#Gives the option of starting over.
#This version should count your turns for you, down from ten.

use strict;
use warnings;

#This is how many guesses you get.
my $max_guesses = 10;

sub game
{
    #This is the number they have to guess: a random integer.
    my $value = int(rand(200));

    print "Pick a number between 0 and 200.\n";

    for (my $tries = $max_guesses; $tries; --$tries) {
        print "You have ", $tries, " guesses left.\n";
        my $guess = <STDIN>;
        if($guess>$value) {
            print "You need to guess a lower number.\n";
            print "Guesses left: ", $tries, "\n";
        } elsif($guess<$value) {
            print "You need to guess a higher number.\n";
            print "Guesses left: ", $tries, "\n";
        } else {
            print "You guessed my number in ", 
                $max_guesses - $tries,
                " guesses.  Thanks for playing. \n";
            return;
        }
    }

    print "Sorry, you ran out of guesses.  My number was ", $value, ".
+\n";
}

my $again = 'y';
while ($again eq 'y')
{
    game();
    print "Play Again? (y/n) \n";

    $again = <STDIN>;
    chomp ($again);
}
print "Goodbye!\n";
[download]