I've done this before like so: 

my %People;
while(  my $id= GetNextId()  ) {
    my( $name, $age, $addr, $city, $state, $phone )=
      GetDataForId( $id );
    my $record=  { NAME=>$name, AGE=>$age, ADDR=>$addr,
      CITY=>$city, STATE=>$state, PHONE=>$phone };
    warn "Duplicate ID numbers: $People{ID}{$id} vs. $name\n"
      if  $People{ID}{$id};
    $People{ID}{$id}= $record;
    foreach my $field (  qw( NAME AGE STATE PHONE )  ) {
        push @{ $People{$field}{ $record->{$field} } }, $record;
    }
}
print "(The first) John Smith is ",
  "$People{NAME}{'John Smith'}[0]{AGE} years old.\n";
print "There are ",0+@{$People{AGE}{20}}, " 20-year-olds:\n";
foreach my $person (  @{ $People{AGE}{20} }  ) {
    print "\t",$person->{NAME},"\n";
}

[download]
Note how easy it is to extend to index on more fields. If this confuses you, then you can change to code to prepend "By" to each field name for indices so you write: 
print "(The first) John Smith is ",
  "$People{ByNAME}{'John Smith'}[0]{AGE} years old.\n";

[download]
instead.

Note how each level is a reference so if you are dealing with one part over and over you can make short cuts: 

my $byID= $People{ID};
foreach my $person (  @$byID  ) {
}

[download]
and that each of the many ways of getting at the data all get to the same copy of the data so you aren't wasting space and can update the data via any way you get to it.

        - tye (but my friends call me "Tye")

In reply to (tye)Re: Complex Data Structures? by tye
in thread Complex Data Structures? by Anonymous Monk

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.