My Haskell implementation represents numbers as the ratio of products of ordered integer streams. For example, I represent 3!/(4*5) as (R numerator=[1,2,3] denominator=[4,5]). In this representation, multiplication becomes merging the numerator and denominator streams and then canceling the first stream by the second. In this way I can remove all cancelable original terms in the P_cutoff formula before finally multiplying the terms that remain.

*FishersExactTest> fac 6
R {numer = [2,3,4,5,6], denom = []}
*FishersExactTest> fac 3
R {numer = [2,3], denom = []}
*FishersExactTest> fac 6 `rdivide` fac 3
R {numer = [4,5,6], denom = []}
[download]

Here's the example from the MathWorld page:

*FishersExactTest> rpCutoff [ [5,0],
                              [1,4] ]
R {numer = [2,3,4,5], denom = [7,8,9,10]}
*FishersExactTest> fromRational . toRatio $ it 
2.3809523809523808e-2
[download]

The code:

module FishersExactTest (pCutoff) where

import Data.Ratio
import Data.List (transpose)

pCutoff = toRatio . rpCutoff

rpCutoff rows =
    facproduct (rs ++ cs) `rdivide` facproduct (n:xs)
  where
    rs = map sum rows
    cs = map sum (transpose rows)
    n  = sum rs
    xs = concat rows -- cells

facproduct = rproduct . map fac

fac n | n < 2     = runit
      | otherwise = R [2..n] []

-- I represent numbers as ratios of products of integer streams
-- R [1,2,3] [4,5] === (1 * 2 * 3) / (4 * 5)

data Rops = R { numer :: [Int], denom :: [Int] } deriving Show

runit             = R [] [] -- the number 1
toRatio (R ns ds) = bigProduct ns % bigProduct ds
bigProduct        = product . map toInteger

-- multiplication is merging numerator and denominator streams
-- and then canceling the first by the second

rtimes (R xns xds) (R yns yds) =
    uncurry R $ (merge xns yns) `cancel` (merge xds yds)

rproduct = foldr rtimes runit

-- division is multiplication by the inverse

rdivide x (R yns yds) = rtimes x (R yds yns)

-- helpers

merge (x:xs) (y:ys)
    | x < y     = x : merge xs (y:ys)
    | otherwise = y : merge (x:xs) ys
merge [] ys     = ys
merge xs []     = xs

cancel (x:xs) (y:ys)
    | x == y    = cancel xs ys
    | x < y     = let (xs', ys') = cancel xs (y:ys) in (x:xs', ys')
    | otherwise = let (xs', ys') = cancel (x:xs) ys in (xs', y:ys')
cancel xs ys    = (xs, ys)
[download]

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.