use strict;
use warnings;

use Math::Combinatorics;
use Algorithm::Loops qw( NestedLoops );
use Data::Dumper;
use List::Util qw(max);
use Benchmark qw(:all) ;

sub find_lances_holli
{
    my $mechs    = shift;
    my $players  = shift;
    my $weight   = shift;
    my $treshold = shift;
    
    
    my @all_lances = Math::Combinatorics::combine ($players, @_);
    
    my @valid_lances;
    
    for my $lance ( @all_lances )
    {
        my $sum;
 
        $sum += $mechs->{$_}{weight}
            for @{$lance};
        
        push @valid_lances, { names=>$lance, weight=>$sum }
            if ($weight - $sum <= $treshold) && ($weight - $sum) >= 0 
+;
    }
    
    return @valid_lances;
}


sub find_lances_tye
{
    my( $hvMechs, $members, $maxWeight, $treshold )= @_;
    my @mechs= keys %$hvMechs;
    
    my $iter= NestedLoops
    (
        [ [0..$#mechs], (sub{[$_+1..$#mechs]})x($members-1) ],
        {
            OnlyWhen => sub 
            {
                return   if  @_ != $members;
                my $weight= 0;
                $weight += $_->{weight}  for  @$hvMechs{@mechs[@_]};
                #return $weight == $maxWeight;
                return 1                        
                    if ($maxWeight - $weight <= $treshold) && ($maxWei
+ght - $weight) >= 0 ;
            },
        }
    );
    
    my $getit= sub 
    {
        my @idx= $iter->();
        my $w = 0;
        
        return unless @idx;
        
        $w+=$hvMechs->{$_}->{weight} for @mechs[ @idx ];
        
        return { weight=>$w, names => [@mechs[ @idx ]] }
            if @idx;
    };
    my (@ret,$item);
    push @ret,$item while $item=$getit->();
    return @ret;
}

# make_choose_iter( $choose, @list )
# ------------------------------------------------------
# Returns an anonymous subroutine to act as an iterator
# over the set of combinations, returning each in turn
# every time it is called. If the iter is called with an
# argument or the list has been exhausted on a previous run
# it resets itself and returns undef.
#

sub make_choose_iter {
    my ( $choose, $list )= @_;

    die "Can't do ".(0+@$list)." choose ".($choose||0)."\n"
        if $choose>@$list or !@$list or !$choose;

    $choose--;  # 1 based number passed in, but need it 0 based

    # done is used as a flag, and @idx is the first n positions
    my ( $done, @idx )= ( 0, 0 .. $choose );

    return sub {
        if ( $done || @_ ) {
            # if we finished the list last call, or they are
            # forcing a reset via an argument
            # then we reset everthing and return undef/empty list
            ($done , @idx)= ( 0, 0 .. $choose );
            return;
        }
        # we get the apropriate elements of the list for the
        # current state of @idx. this is what we will return
        my @ret= @{$list}[@idx];

        # assume that this is the last element.
        $done= 1;
        # Loop over the elements of @idx from the right
        # looking for the correct element:
        # We are simulating the behaviour of N
        # nested loops. This means we increment the
        # rightmost element whose increment does not
        # overflow and whose final value is sufficiently
        # low that the elements following it can be filled
        # with its successors without also overflowing
        for ( my $i= $choose ; $i >= 0 ; $i-- ) {
            if ( #$idx[$i] < $#$list
                 #&& 
                 (my $end= $idx[$i] + 1 + $choose - $i) < @$list )
            {
                $idx[$i]++;
                @idx[ $i + 1 .. $choose ]= ( $idx[$i] + 1 .. $end );
                $done= 0;
                last;
            }
        }
        return wantarray ? @ret : \@ret;
    };
}

sub find_lances_demerphq 
{
    my ($mechs,$count,$weight,$treshold)=@_;

    #print Dumper ($mechs);<STDIN>;
    my $iter= make_choose_iter( $count, [values %$mechs] );
    my @ret;
    while (my $items=$iter->()) 
    {
        my $sum=0;
        
        #print Dumper ($items);<STDIN>;
        
        $sum+=$_->{weight} for @$items;
        if (($weight - $sum <= $treshold) && ($weight - $sum) >= 0) {
            my $combo = { weight => $sum, names => [ map { $_->{name} 
+} @{$items} ] }; 
        
            push @ret, $combo
        }
    }

    return @ret;
}

  

my %mechs;
my @holli;
my @tye;
my @demerphq;
my $iter;


while (<DATA>)
{
    chomp;
    my ($mech, $weight, $faction) = split /\s+/;
    $mechs{$mech} = { name => $mech, weight => $weight, faction => $fa
+ction };
}
my $candidates={
        'tye'   => sub { @tye  = find_lances_tye   ( \%mechs, 5, 240, 
+10 ) },
        'holli' => sub { @holli = find_lances_holli ( \%mechs, 5, 240,
+ 10, keys %mechs ) },
        'demq'  => sub { @demerphq = find_lances_demerphq ( \%mechs, 5
+, 240, 10 ) },
    };
    
timethese(-10, $candidates);    
cmpthese(-10, $candidates);


for my $array (\@holli,\@tye,\@demerphq) {
    @$array= sort map { 
                join (",", sort @{$_->{names}}) . "(" . $_->{weight} .
+ " tons)\n" 
             } @$array;
             
}


my $ok = join ("", @holli) eq join ("", @tye) && 
         join ("", @demerphq) eq join ("", @tye) ? "" : " not";

print "output$ok identical\n";         


__DATA__
Flea 20 clan
Commando 25 clan
UrbanMech 30 clan
Hollander 35 clan
Jenner 35 clan
Raven 35 clan
Wolfhound 35 clan
BlackHawk 50 clan
Hunchback 50 clan
Rifleman 60 clan
Catapult 65 clan
Loki 65 clan
Thor 70 clan
MadCat 75 clan
Gargoyle 80 clan
Victor 80 clan
Zeus 80 clan
Longbow 85 clan
Warhawk 85 clan
Mauler 90 clan
Atlas 100 clan
[download]