Increase the scope of @dirlist: 

use File::Find;

my @dirlist;

sub wanted {
   return unless -d $_;
   push(@dirlist, $File::Find::name);
}

find(\&wanted, shift(@ARGV));

# Use @dirlist here

[download]

Closures come in useful if you'd wish to avoid using a global: 

use File::Find;

sub find_dirs {
   my @dirlist;
   find(sub {
      return unless -d $_;
      push(@dirlist, $File::Find::name);
   }, @_);
   return @dirlist;
}

{
   # Not a global.
   my @dirlist = find_dirs(shift(@ARGV));

   # Use @dirlist here
}

[download]

Yet another way. This one uses dynamically scoped variables: 

use File::Find;

sub wanted {
   return unless -d $_;
   push(@File::Find::matches, $File::Find::name);
}

sub find_it {
   local *File::Find::matches;
   find(@_);
   return @File::Find::matches;
}

{
   # Not a global.
   my @dirlist = find_it(\&wanted, shift(@ARGV));

   # Use @dirlist here
}

[download]

Update: Added 2nd snippet.
Update: Added 3rd snippet.

In reply to Re: Return values, Closure Vars from File::Find &wanted subs? by ikegami
in thread Return values, Closure Vars from File::Find &wanted subs? by Subliminal Kid

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.