Here's a version that approximates your desired usage without gotos or source filters, and it's not obfuscated, IMO. Each yield section gets its own sub, and they're all wrapped in a sub that sets up the variables for the coroutine scope. 
use warnings;
use strict;

package Coroutine;
sub prototype {
    my $class = shift;
    bless shift(), $class;
}
sub instance {
    my $self = shift;
    my @sections = $self->(@_);

    return sub {
      return () unless @sections;
      (shift @sections)->(@_);
    }
}

package main;

my $coroutine = Coroutine->prototype(
    sub {
        my $foo = shift;
        my @bar = @_;
        (
          sub {
            print "1st section:\n";
            print " $_\n" for @bar;
            return $foo++;
          },
          sub {
            print "2nd section:\n";
            print " $foo\n";
            return rand() > .5 ? 'weird' : ++$foo;
          },
          sub {
            print "3rd section:\n";
            print " The end is near - goodbye cruel ";
            return pop @bar;
          }
        )
    }
);

my $wacky = $coroutine->instance(42, 'hello', 'world');
print "returned($_)\n" while ($_ = $wacky->());
print "Resetting...\n";
$wacky = $coroutine->instance('another', 'time', 'through');
print "returned($_)\n" while ($_ = $wacky->());
__END__
1st section:
 hello
 world
returned(42)
2nd section:
 43
returned(44)
3rd section:
 The end is near - goodbye cruel returned(world)
Resetting...
1st section:
 time
 through
returned(another)
2nd section:
 anothes
returned(anothet)
3rd section:
 The end is near - goodbye cruel returned(through)

[download]
Caution: Contents may have been coded under pressure.

In reply to (non-)Obfu Coroutines by Roy Johnson
in thread Obfu Coroutines by Limbic~Region

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.