If you want to track entry and exit to all subroutines, the easiest way is to write a custom debugger. It's actually very easy: 
# This is the custom debugger:
{ package DB;
  sub DB {}
  sub sub {
    print STDERR "== Entering sub $sub\n";
    &$sub; # Call the sub
    print STDERR "=== Leaving sub $sub\n";
  }
}

# Now some example code to test it with:
sub hello {
  print "Hello, ";
  world();
}

sub world {
  print "World!\n";
}

$|++;   # Turn off buffering, to make the control flow clearer
hello();

[download]
The debugging code will only be activated if you run with perl -d, so: 
$ perl d.pl
Hello, World!
$ perl -d d.pl

Loading DB routines from perl5db.pl version 1.28
Editor support available.

Enter h or `h h' for help, or `man perldebug' for more help.

== Entering sub main::hello
Hello, == Entering sub main::world
World!
=== Leaving sub main::world
=== Leaving sub main::hello

[download]
See perldebguts for all the gory details.

Update: As a (probably better) alternative to running perl -d, you can use 

  BEGIN {$^P = 1}

[download]
to enable subroutine-tracing. That way you don't need the empty sub DB either. But woe betide you if you should actually run with perl -d. Maybe it's best to use something like 
BEGIN {
  return if $^P;  # If the debugger is running, leave well alone
  $^P = 1;        # Enable subroutine tracing
  package DB;
  *sub = sub {
    print STDERR "== Entering sub $sub\n";
    &$sub;
    print STDERR "=== Leaving sub $sub\n";
  };
}

[download]

In reply to Re: Tweaking 'return'. by robin
in thread Tweaking 'return'. by eff_i_g

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.