#!/usr/bin/perl
use strict;
use warnings;
use Benchmark 'cmpthese';

my $str = build_str();
cmpthese -5, {
    by_fh => sub  {
        my @offsets;
        local $/ = "\n";
        open(my $fh, '<', \$str) or die "Unable to use str as fh: $!";
        push @offsets, (tell $fh) - 1 while <$fh>;
    },
    by_index => sub {
        my @offsets;
        my $p = 0;    
        do {
            $p = index($str, qq(\n), $p);
            push @offsets, $p++;
        } while $p > 0;
        pop @offsets;
    },
    by_regex1 => sub {
        my @offsets;
        $str =~ s/\n/push @offsets, $-[0];"\n"/ge;  
    },
    by_regex2 => sub {
        my @offsets;
        push @offsets, pos($str) - 1 while $str =~ /\n/g;
    },
    by_regex3 => sub {
        my @offsets;
        push @offsets, $-[0] while $str =~ /\n/g;
    },
};

sub build_str {
    my ($str, $max) = ('', 200 * 1024);
    while ( length($str) < $max ) {
        # Assume lines are between 60-79 characters long
        $str .= ('#' x ((rand 20) + 60)) . "\n";
    }
    return $str;
}
[download]