I wrote this mainly because someone asked how to do this in PHP. Turns out there is nothing in like the venerable URI module in all of PHP-dom (how pathetic is that for a language as web-centric as it?).

First, I tried writing this with mostly string functions, but that was too painful, so I switched to doing it using regexes, even though they’re piss-poorly supported. After a while, my eyes glazed over, so I resorted to writing and debugging the code in Perl first, and then compiling it down to machine code PHP.

I thought I’d post this byproduct here for posterity, in case someone needs it in some circumstance.

Tests included, but I’m pretty sure they’re not extensive enough to be 100% confident in the code. Proceed at your discretion.

sub abs_url {
    my ( $relative, $base ) = @_;

    return $relative if $relative =~ m{ \A http:// }ix;

    my ( $host, $hostrelative_abs ) = $base =~ m{
        \A
        http:// # skip scheme
        ([^/]*) # capture hostname
        /*      # skip front slashes
        (.*?)   # capture everything that follows, but
        [^/]*   # leave out the optional final non-directory component
        \z
    }ix;

    $hostrelative_abs = '' if $relative =~ m!^/!;

    my $abs_url = join '/', $host, $hostrelative_abs, $relative;

    # replace '//' or '/./' with '/'
    1 while $abs_url =~ s{ / \.? (?=/|\z) }{}x;

    # remove '/foo/..' (but be careful to skip '/../..')
    1 while $abs_url =~ s{ / (?!\.\.) [^/]+ / \.\. (?=/|\z) }{}x;

    return "http://$abs_url";
}

[download]
use Test::More;
my @test = qw(
 /foo/bar.gif      http://www.example.com/baz/quux/    http://www.exam
+ple.com/foo/bar.gif
 foo/bar.gif       http://www.example.com/baz/quux/    http://www.exam
+ple.com/baz/quux/foo/bar.gif
 ../../bar.gif     http://www.example.com/baz/quux/    http://www.exam
+ple.com/bar.gif
 foo/bar.gif       http://www.example.com/baz/quux     http://www.exam
+ple.com/baz/foo/bar.gif
 ../foo/bar.gif    http://www.example.com/baz/quux     http://www.exam
+ple.com/foo/bar.gif
 ../../foo/bar.gif http://www.example.com/baz/quux/qux http://www.exam
+ple.com/foo/bar.gif
);
plan tests => @test / 3;
do { is abs_url( $test[0], $test[1] ), $test[2]; splice @test, 0, 3 } 
+while @test;

[download]

In reply to Convert relative to absolute URL given a base URL, without modules by Aristotle

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.