• my $ns = GetNamespace("MAPI");
  should probably be
  my $ns = $Outlook->GetNamespace("MAPI");

• Yes, return; is indeed the equivalent of Exit Sub.

• Your indentation is inconsistent, making your code hard to read.

• $i serves no purpose. Same as in the VB code.

• $ol is never used either.

• $Atmt is never assigned a value. Change

  my $Item;
  my $Atmt;
  ...
  foreach (in $Inbox->Items) {
     foreach (in $Atmt->Item->Attachments) {
  [download]

  to

  foreach my $Item (in $Inbox->Items) {
     foreach my $Atmt (in $Item->Attachments) {
  [download]

• The following (and the VB equivalent) is useless since the variables get freed when they go out of scope:

  undef $Atmt;
  undef $Item;
  undef $ns;
  [download]

• The return at the end of the function is useless.

So we get:

#! perl

use strict;
use warnings;

use File::Spec ();
use Win32::OLE qw( in ); 
use Win32::OLE::Const 'Microsoft Outlook';

my $SAVE_FOLDER = 'G:\Input';

my $Outlook = Win32::OLE->new('Outlook.Application', 'Quit');

Detach_files();

sub Detach_files {
   my $ns = $Outlook->GetNamespace('MAPI');
   my $Inbox = $ns->GetDefaultFolder(olFolderInbox);

   return if $Inbox->Items->{Count} == 0;
    
   foreach my $Item (in $Inbox->Items) {
      # Check each message for attachments.
      foreach my $Atmt (in $Item->Attachments) {
         # Save any "Flat_file_" attachments found.
         my $FileName = $Atmt->FileName;
         if ($FileName =~ /^Flat_file_/) {
            $FileName = File::Spec->catdir($SAVE_FOLDER, $FileName);
            $Atmt->SaveAsFile($FileName);
         }
      }
   }
}
[download]

Untested.

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.