Text::Balanced will take care of the nested parentheses.

Update:

Here's a script to parse your data into a hash of hashes.

To get access to long_name, for example, just use $href->{info}->{english}->{long_name}: 

use Text::Balanced qw(extract_bracketed);

my $rex  = qr/(?s):(\w+) (\(.*)/;
my $href = {};

my $data = join '', <DATA>;

extract($data, $href);

print $href->{info}->{english}->{long_name},
      "\n";

###########################################
sub extract {
###########################################
  my($input, $href) = @_;

  while($input =~ /$rex/) {

      my($tok, $str) = ($1, $2);

      my ($extr, $rest) = extract_bracketed($str, '()');

      if($extr =~ /$rex/) {
        $href->{$tok} = {};
        extract($extr, $href->{$tok});
      } else {
        $extr =~ s/^\(|\)$//g;
        $href->{$tok} = $extr;
      }

      $input = $rest;
  };

  return $href;
}

__DATA__
("TELNET:OVERFLOW:OPTIONS-REPLY"
  :info (
    :english (
      :name ("TELNET:OVERFLOW:OPTIONS-REPLY")
      :long_name ("TELNET Options Overflow (Response)")
      :description ("This signature detects attempts to
        exploit a known vulnerability against the BSD-based TELNET
        daemon. The option processing function (telrcv) in the daemon
        produces responses with a fixed size buffer, but does not
        perform bounds checking. Attackers can send a combination of
        TELNET protocol options to the daemon to overflow the buffer
        and execute arbitrary commands.")
    ) 
  ) 
  :color (red) 
  :severity (5) 
  :category (TELNET)
  :keywords ("telnet dangerous command bin") 
)

[download]

In reply to Re: Tricky parsing. by saintmike
in thread Tricky parsing. by lostriver

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.