local and our are completely unrelated. For now, let's expand the code and look at the statements individually.

our $bob;
local $bob;
$bob = 'bob';
[download]

• our $bob; disables use strict 'vars' for $bob for the remainder of current scope. It allows you to use package variable $bob without its package name where you might have had to without our $bob;. [Note that this is a bit of an oversimplification. (Upd)]

• local $bob; saves the current value of $bob (and sets $bob to undef). When the scope is exited (whether normally or by exception), $bob reclaims the value saved by local $bob.

• $bob = 'bob'; assigns a value to $bob.

Now, let's put these into context.

Say you wish to take advantage of dynamic scoping. That means you need to use a package variable, not a lexical (my) variable. To avoid having to specify the package name when using that package variable, you use our. Let's also say you wish to protect the value that's currently being held by this variable. local would be used.

Why would you want to use dynamic scoping? Maybe you want to override a global option temporarily. For example,

use strict;
use warnings;

package MyModule;

sub do_it {
   my ($arg) = @_;
   our $VERBOSE;

   ...

   warn(...)
      if $VERBOSE;

   ...
}

sub do_it_quietly {
   my ($arg) = @_;
   our $VERBOSE;    # Avoid saying $MyModule::VERBOSE
   local $VERBOSE;  # Save existing value.
   $VERBOSE = 0;    # Disable logging.

   do_it($arg);
}

1;
[download]

Finally, since local and our return their arguments as lvalues, it's possible to chain these functions. For example, the following are all equivalent:

• our $VERBOSE; local $VERBOSE; $VERBOSE = 0;
• our($VERBOSE); local($VERBOSE); $VERBOSE = 0;
• local(our($VERBOSE)) = 0;
• local our $VERBOSE = 0;

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.