Hi Cody,

If you extract in 'tree' mode then the returned structure is actually a full-fledged HTML::ElementTable object. Example usage similar to what you seem to want: 

#!/usr/bin/perl

use strict;
use warnings;

# load in 'tree' mode for working with
# HTML::Element structures. note that in
# this case, subtables are *not* decoupled
# from one another.

use HTML::TableExtract 'tree';

my $te = HTML::TableExtract->new(
  # extraction parameters here...note that
  # in tree mode, keep_html is irrelevant
);
$te->parse_file("./myfile.html");

my $t = $te->first_table_found or die "oops, no tables.\n";

# at this point we can work with $t->rows and the
# cells within, but rather than text or html, the
# content is now individual element objects/trees

# for html...
print "H::TE as html:\n";
foreach my $row ($t->rows) {
  print join(':', map { $_->as_HTML } @$row), "\n";
}

# for text...
print "H::TE as text:\n";
foreach my $row ($t->rows) {
  print join(':', map { $_->as_text } @$row), "\n";
}

# Alternatively, you could switch entirely over
# to the HTML::ElementTable structure

my $et = $t->tree;

# as html
print "H::ET as html:\n";
print $et->as_HTML, "\n";

# as text
print "H::ET as text:\n";
print $et->as_text, "\n";

[download]

Cheers,
Matt

In reply to Re: Extracting from HTML tables by mojotoad
in thread Extracting from HTML tables by Cody Pendant

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.