#!/usr/bin/perl
use strict;
use warnings;

=head1 NAME

jsxray-proxy - A JavaScript::XRay proxy

=head1 SYNOPSIS

 jsxray [options]

  Options:
   -port
   -switches
   -no-xray
   -help
   -man

=head1 DESCRIPTION

Straps L<HTTP::Proxy> onto L<JavaScript::XRay> so I can use
JavaScript::XRay really easily and on arbitrary web sites.

=over

=item -port ...

Specifies a port to listen on. The default is 8080.

=item -switches

Specifies switches to use for JavaScript::XRay. Prefix your switch wit
+h no- to pass it as a turned off switch.

=item -no-xray

Doesn't install JavaScript::XRay. It's just a simple proxy now.

=item -help

Displays the program's options.

=item -man

Displays the entire manual.

=back

=cut

use Getopt::Long 'GetOptions';
use autouse 'Pod::Usage', 'pod2usage';

GetOptions(
    help         => \&help,
    man          => \&man,
    'port=i'     => \( my ($port) = 8080 ),
    'switches=s' => \( my ($switches) = 'all' ),
    'no-xray'    => \my ($no_xray)
    )
    or pod2usage( -verbose => 0 );
sub help { pod2usage( -verbose => 1 ) }
sub man  { pod2usage( -verbose => 2 ) }

require HTTP::Proxy;
my $proxy = HTTP::Proxy->new( port => $port );

if ( not $no_xray ) {
    require HTTP::Proxy::BodyFilter::simple;
    require JavaScript::XRay;

    my %switches = map { /^no-(.+)/ ? ( $1 => 0 ) : ( $_ => 1 ) }
        $switches =~ /((?:no-)?[a-z]+)/g;

    my $filter = HTTP::Proxy::BodyFilter::simple->new(
        sub {
            return unless $_[2]->header('content-type') =~ /text/;
            my $uri  = $_[2]->request->uri;
            my $xray = JavaScript::XRay->new(
                abs_uri  => $uri,
                switches => \%switches
            );

            ${ $_[1] } = $xray->filter( ${ $_[1] } );
        }
    );

    $proxy->push_filter( response => $filter );
}

$proxy->start;
[download]

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.