Jeff Goldblum Actor
Mary Heartman Priest
John Ericsson Mathmetician
Tony Cisneros Chef


How can I sort on Vocation?
[download]

Well, there's lots of ways of course!

First off, I don't see any multidimensional array in your example. I just see a list of data. So let's make it a real multidimensional array:

my @data = ( [ qw(Jeff Goldblum Actor) ],
             [ qw(Mary Heartman Priest) ],
             [ qw(John Ericsson Mathmetician) ],
             [ qw(Tony Cisneros Chef) ], );
[download]

Ok, so now we have an array with 4 elements, each of which is a reference to an array of 3 elements. So now you want to sort on the Vocation, which is the third field. There are many approaches...personally I'm old school, and am a sworn Schwartzian Transform kind of guy:

my @sorted = map  { $_->[0] }              # Line 4
             sort { $a->[1] cmp $b->[1] }  # Line 3
             map  { [ $_, $_->[2] ] }      # Line 2
             @data;                        # Line 1
[download]

What the heck does that do? Read it backwards:

1. Line #1 is your original list
2. Line #2 - For each element in the original list, create an anonymous array of two elements: The first element in the array is the element fed in from the original array. The second element is field 2, which is the value of Vocation, or what you wanted to sort by
3. Line #3 - Sort those anonymous arrays by field 1 (Vocation)
4. Line #4 - As those anonymous array come out of sort, remap them to the original element from the unsorted @data.

my @data = ( [ qw(Jeff Goldblum Actor) ],
             [ qw(Mary Heartman Priest) ],
             [ qw(John Ericsson Mathmetician) ],
             [ qw(Tony Cisneros Chef) ], );


my @sorted = map  { $_->[0] }              # Line 4
             sort { $a->[1] cmp $b->[1] }  # Line 3
             map  { [ $_, $_->[2] ] }      # Line 2
             @data;                        # Line 1

for ( @sorted ) {
   printf "%s %s - %s\n", @{ $_ };
}
[download]

fappy@flux[16] perl /tmp/sortit
Jeff Goldblum - Actor
Tony Cisneros - Chef
John Ericsson - Mathmetician
Mary Heartman - Priest
[download]

Hope this helps some,

~Jeff

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.