Tabs would be useful if you could define the tab stops.

A solution: 

use List::Util qw( max );

my $max_spam_len = max map length, 'Spam:', @spam;
my $format = "%-${max_spam_len}s  %s\n";

printf($format, 'Spam:', 'Ham:');

my $max_idx = max $#spam, $#ham;
for my $i (0..$max_idx) {
   printf($format,
      $i <= $#spam ? $spam[$i] : '',
      $i <= $#ham  ? $ham[$i]  : '',
   );
}

[download]

Update: A more generic solution: 

use List::Util qw( max );

sub print_columns {
   my ($data) = @_;

   my @headers;
   my @columns;

   for (my $i = 0; $i < @$data; ) {
      push(@headers, $data->[$i++]);
      push(@columns, $data->[$i++]);
   }

   my @col_widths = map {
      max map length, $headers[$_], @{$columns[$_]}
   } 0..$#headers;
   my $format = join('  ', map "%-${_}s",   @col_widths) . "\n";
   my $sep    = join('  ', map { '-' x $_ } @col_widths) . "\n";

   printf($format, @headers);
   print($sep);

   my $max_idx = max map { $#$_ } @columns;
   for my $i (0..$max_idx) {
      printf($format, map { $i < @$_ ? $_->[$i] : '' } @columns);
   }
}

print_columns([
   Spam => \@spam,
   Ham  => \@ham,
]);

[download]

Tested.

In reply to Re: Am i formatting correctly? (auto-sizing columns) by ikegami
in thread Am i formatting correctly? by dark314

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.