You were very close to solving the problem. You just need to repeat the search multiple times, as perl will continue the search when the last one ended. 
use strict;
use warnings;
use Data::Dumper;

my $data;

# Modifying $/ in a limited context to avoid 
# affecting other areas of the code.
{
  local $/;
  $data = <DATA>;
}


#
# Create the regular expression using qr{}x as it makes
# the pattern much easier to follow (and maintain)
#
my $pattern = qr{
  (\d+-)
  (\d+-)
  (\d+)
  (\s*/\s*)
  (\d+)
  (\s*/\s*)
  (\d+)
}x;

my @list;
while ($data =~ /$pattern/g) {
  push @list,[$1,$2,$3,$4,$5,$6,$7];
}
print Dumper \@list;

__DATA__
      PART NAME         QUANTITY    SECTION/FIGURE/ITEM

      Widget1               1       72-33-00/ 23/ 85
      Widget1               1       75-20-00/ 11/ 10
      Widget2               1       72-33-00/20/10
      Widget2               1       72-33-00/20/70
      Widget2               1       72-00-33/2/1
      Widget2               1       72-00-33/2/20
      Widget2               1       73-12-00/4/1
      Widget2               1       73-12-00/4/220
      Widget2               1       73-12-00/3/10
      Widget2               2       79-20-00/9/1
      Widget2               1       79-20-00/5/1

[download]
Note that I defined the regex before the loop. This makes the logic easier to follow, particularly when you use the 'x' modifier.

In reply to Re: How to capture all occurances from a slurped file. by imp
in thread How to capture all occurances from a slurped file. by Grey Fox

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.