• In scalar context, an array returns the number of elements it contains. That means my $game = @_; assignes the number of arguments (1) to $game. Force the assignment into a list context.
  my $game = @_;
  should be
  my ($game) = @_;

• All instances of @$game in your sub should be @maps. Don't forget to do my @maps;. There's no reason for the array to be named after the game, which is what you are trying to do with symbolic references (which are almost always bad and causing some of your errors).

• array is an aweful name for that sub. What about get_game_maps?

• my $map; foreach $map (@maps)
  can be written more concisely as
  foreach my $map (@maps)

• Your function returns a list of maps, but you discard the return value.
  MAP::array("cstrike");
  should be
  my @cstrike_maps = MAP::array("cstrike");

• Congrats for using use strict;. You should also use use warnings;. Warnings almost always point to an error. ( Oops! I see you used -w. I'd put use warnings; in the module explicitely. You shouldn't rely on the calling script using -w. )

• use vars qw( @ISA ); @ISA = qw( Exporter );
  can be written more concisely as
  our @ISA = qw( Exporter );

• Handle MAPS should be localized. Better yet, it should be a lexical (my) variable.

use strict;
use warnings;
use diagnostics;

package MAP;

use Exporter ();

our $VERSION     = 1.00;
our @ISA         = qw( Exporter );
our @EXPORT      = ();
our @EXPORT_OK   = qw( get_game_maps );

sub get_game_maps
{
        # Declare Variables
        my ($game) = @_;
        my $user = $ENV{'USER'};

        # Create Dir Path
        my $dir = "/home/$user/hlds_l/$game/maps/";

        # We're done if the dir does not exist.
        return unless -d $dir;

        opendir(my $maps_dh, $dir) || die("Cannot open directory");
        my @maps = readdir($maps_dh);
        closedir($maps_dh);

        # Take only maps and trim .bsp
        @maps = grep /\.bsp\z/, @maps;

        foreach my $map (@maps)
        {
                $map =~ s/\.bsp\z//;
        }

        return @maps;
}

1;
# end
[download]

#!/usr/bin/perl5

use strict;
use warnings;
use diagnostics;

# Load Module
use MAP;

# Call Routine
my @cstrike_maps = MAP::get_game_maps("cstrike");

# Print returned array
foreach my $map (@cstrike_maps)
{
        print "$map\n";
}
[download]

Update: A more consice version of the sub:

use List::Util qw( apply );

sub get_game_maps
{
        my ($game) = @_;

        my $user = $ENV{'USER'};
        my $dir = "/home/$user/hlds_l/$game/maps/";

        # We're done if the dir does not exist.
        return unless -d $dir;

        opendir(my $maps_dh, $dir)
                or die("Cannot open directory");

        return apply { s/\.bsp\z// }
               grep  { /\.bsp\z/ }
               readdir($maps_dh);
}
[download]

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.