(... for unix/linux folks only) The problem posed by this SoPW node implies a need to quickly perform a scan for hard links: given a path to search in, and a target file whose inode number may be tied to some number of hard links under that path, find those links (i.e. all references to that inode number), and ditch out as soon as you've found them.

Since timing is an issue, the general slowness of File::Find (relative to the compiled "find" command) could pose a real problem -- especially on very large directory trees -- so the challenge is: how to get the find command to do the right thing, and quit when there are no more links to be found?

The cool thing here is how the IPC is done: child sends HUP signals to the parent each time a link is found (via the "-exec" option on unix find), parent closes everything up as soon as the expected link count is reached. 

#!/usr/bin/perl

use strict;
use warnings;

my ( $path, $file ) = @ARGV;
die "Usage: $0  search/path  data.file\n"
    unless ( -d $path and -f $file );

my ( $inode, $nlinks ) = ( stat _ )[1,3];
die "$file has no hard links\n" if $nlinks == 1;

my ( $chld, $nfound, @found );
$SIG{HUP} = sub { $nfound++; `kill $chld` if $nfound == $nlinks };

$chld = open( FIND, "-|", "find $path -inum $inode -print0 -exec kill 
+-HUP $$ \\;" )
    or die "find: $!\n";

$/ = chr(0);
while ( <FIND> ) {
    chomp;
    push @found, $_;
}

printf( "found %d of %d links for %s in %s:\n",
    scalar @found, $nlinks, $inode, $path );
print join( "\n", @found ), "\n";

[download]

In reply to Another way to avoid File::Find by graff

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.