If you're just trying to validate, then it's doable, but you'll need to use an advance trick ((??{ ... })) to handle parentheses. I actually used more regexps than necessary in my solution below — all but $expr can be inlined — but it makes it shorter and more readable. 

use strict;
use warnings;

sub is_valid_expr {
   use re 'eval';
   local our ($skip, $term, $expr);
   $skip = qr! \s* !x;
   $term = qr! $skip [a-zA-Z]+
             | $skip [1-9][0-9]*
             | $skip \( (??{ $expr }) $skip \) !x;
   $expr = qr! $term (?: $skip [-+*/] $term )* !x;
   return $_[0] =~ / ^ $expr $skip \z /x;
}

foreach (
   '(a + 3)',
   '(3 * 4)+(b + x)',
   '(5 - a)*z',
   '3 + 2',

   '!3 + 2',
   '3 + 2!',

   '3 a',
   '3 3',
   '3 * * 3',

   '2 - 3 * 4',  # Preceedence test.
   '2 - 3 + 4',  # Associativity test.
) {
   print(is_valid_expr($_)
      ? "$_ is valid\n"
      : "$_ is not valid\n"
   );
}

[download]

Writting a parse using this method would be needlessly difficult. May I recommend that you start with Parse::RecDescent?

Update: For the truly insane: 

sub is_valid_expr {
   local our $expr;
   $expr = qr!(?:\s*[a-zA-Z]+|\s*[1-9][0-9]*|\s*\((??{$expr})\s*\))(?:
+\s*[-+*/](?:\s*[a-zA-Z]+|\s*[1-9][0-9]*|\s*\((??{$expr})\s*\)))*!;
   return $_[0] =~ /^$expr\s*\z/;
}

[download]

Update: Added ysth and diotalevi's fixes.

In reply to Re: Complex regex for maths formulas by ikegami
in thread Complex regex for maths formulas by Anonymous Monk

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.